Create feature collection layer (Portal item)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
// [WriteFile Name=FeatureCollectionLayerFromPortal, Category=Layers]
// [Legal]
// Copyright 2020 Esri.

// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
// http://www.apache.org/licenses/LICENSE-2.0

// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
// [Legal]

import QtQuick 2.6
import QtQuick.Controls 2.2
import Esri.ArcGISRuntime 100.15

Rectangle {
    id: rootRectangle
    clip: true
    width: 800
    height: 600

    MapView {
        id: mapView
        anchors.fill: parent

        Component.onCompleted: {
            // Set the focus on MapView to initially enable keyboard navigation
            forceActiveFocus();
        }

        PortalItem {
            id: portalItem
            itemId: "32798dfad17942858d5eef82ee802f0b"
            Component.onCompleted: load();
            onLoadStatusChanged: {
                if (loadStatus !== Enums.LoadStatusLoaded) {
                    return;
                }

                // if the portal item is a feature collection, add the feature collection to the map's operational layers
                if (type === Enums.PortalItemTypeFeatureCollection) {
                    const featureCollection = ArcGISRuntimeEnvironment.createObject("FeatureCollection", {item: portalItem});
                    const featureCollectionLayer = ArcGISRuntimeEnvironment.createObject("FeatureCollectionLayer", {featureCollection: featureCollection});
                    map.operationalLayers.append(featureCollectionLayer);
                } else {
                    console.warn("Portal item with ID '" + itemId + "' is not a feature collection.")
                }
            }
        }

        Map {
            id: map
            Basemap {
                initStyle: Enums.BasemapStyleArcGISOceans
            }
        }
    }
}